-------------------------------------------------------------------------------
-- Copyright (c) 2003 Mentor Graphics Corporation
--
-- This model is a component of the Mentor Graphics VHDL-AMS educational open 
-- source model library, and is covered by this license agreement. This model,
-- including any updates, modifications, revisions, copies, and documentation 
-- are copyrighted works of Mentor Graphics. USE OF THIS MODEL INDICATES YOUR 
-- COMPLETE AND UNCONDITIONAL ACCEPTANCE OF THE TERMS AND CONDITIONS SET FORTH
-- IN THIS LICENSE AGREEMENT.  Mentor Graphics grants you a non-exclusive 
-- license to use, reproduce, modify and distribute this model, provided that:
-- (a) no fee or other consideration is charged for any distribution except 
-- compilations distributed in accordance with Section (d) of this license 
-- agreement; (b) the comment text embedded in this model is included verbatim
-- in each copy of this model made or distributed by you, whether or not such 
-- version is modified; (c) any modified version must include a conspicuous 
-- notice that this model has been modified and the date of modification; and 
-- (d) any compilations sold by you that include this model must include a 
-- conspicuous notice that this model is available from Mentor Graphics in its
-- original form at no charge.
--
-- THIS MODEL IS LICENSED TO YOU "AS IS" AND WITH NO WARRANTIES, EXPRESS OR 
-- IMPLIED.  MENTOR GRAPHICS SPECIFICALLY DISCLAIMS ALL IMPLIED WARRANTIES OF 
-- MERCHANTABILITY OR FITNESS FOR A PARTICULAR PURPOSE.  MENTOR GRAPHICS SHALL
-- HAVE NO RESPONSIBILITY FOR ANY DAMAGES WHATSOEVER.
-------------------------------------------------------------------------------
-- File       : q_LPF_1st.vhd
-- Author     : Mentor Graphics
-- Created    : 2001/11/09
-- Last update: 2003-05-20
-------------------------------------------------------------------------------
-- Description: 1st order Lowpass Filter with real quantity connections.
-- Includes s and z-domain architectures. 
-------------------------------------------------------------------------------
-- Revisions  :
-- Date        Version     Author              Description
-- 2001/11/09  1.0         Mentor Graphics     Created
-- 2003/04/15  1.1         Mentor Graphics     Added z-domain architecture    
-------------------------------------------------------------------------------
library IEEE;
use ieee.math_real.all;

entity q_LPF_1st is
  generic (
    Fp    :  real;           -- Pole frequency [Hz]
    K     :  real := 1.0;    -- Filter gain
    Fsmp  :  real := 10.0e3  -- For Z-dmn only: Sample frequency (in Hz) 
    );
  port (quantity input  : in  real;
        quantity output : out real);
end entity q_LPF_1st;
-------------------------------------------------------------------------------
-- Transfer Function:
--
--               wp
-- H(s) = K * --------
--             wp + s
-------------------------------------------------------------------------------

-- S Domain Implementation
architecture s_dmn of q_LPF_1st is
  constant wp  : real        := math_2_pi*Fp;  -- Frequency in Radians
  constant num : real_vector := (wp, 0.0);     -- Numerator array 
  constant den : real_vector := (wp, 1.0);     -- Denominator array
begin
  output == K * input'ltf(num, den);    -- Laplace Transfer Function
end architecture s_dmn;

-- Z Domain Implementation (via bilinear transform, no pre-warping)
architecture z_dmn of q_LPF_1st is
  constant Tsmp   : real := 1.0/Fsmp;       -- Sample period
  constant wp     : real := fp*math_2_pi;   -- Pole in rad/s
  constant numz_0 : real := Tsmp*wp;        -- z0 numerator coefficient 
  constant numz_1 : real := Tsmp*wp;        -- z-1 numerator coefficient 
  constant denz_0 : real := Tsmp*wp + 2.0;  -- z0 denominator coefficient 
  constant denz_1 : real := Tsmp*wp - 2.0;  -- z-1 denominator coefficient 
  constant num    : real_vector := (numz_0, numz_1);
  constant den    : real_vector := (denz_0, denz_1);
begin  -- ztf
  output == K*input'Ztf(num, den, Tsmp);
end z_dmn;

-------------------------------------------------------------------------------
-- Copyright (c) 2003 Mentor Graphics Corporation
-------------------------------------------------------------------------------