-------------------------------------------------------------------------------
-- Copyright (c) 2003 Mentor Graphics Corporation
--
-- This model is a component of the Mentor Graphics VHDL-AMS educational open 
-- source model library, and is covered by this license agreement. This model,
-- including any updates, modifications, revisions, copies, and documentation 
-- are copyrighted works of Mentor Graphics. USE OF THIS MODEL INDICATES YOUR 
-- COMPLETE AND UNCONDITIONAL ACCEPTANCE OF THE TERMS AND CONDITIONS SET FORTH
-- IN THIS LICENSE AGREEMENT.  Mentor Graphics grants you a non-exclusive 
-- license to use, reproduce, modify and distribute this model, provided that:
-- (a) no fee or other consideration is charged for any distribution except 
-- compilations distributed in accordance with Section (d) of this license 
-- agreement; (b) the comment text embedded in this model is included verbatim
-- in each copy of this model made or distributed by you, whether or not such 
-- version is modified; (c) any modified version must include a conspicuous 
-- notice that this model has been modified and the date of modification; and 
-- (d) any compilations sold by you that include this model must include a 
-- conspicuous notice that this model is available from Mentor Graphics in its
-- original form at no charge.
--
-- THIS MODEL IS LICENSED TO YOU "AS IS" AND WITH NO WARRANTIES, EXPRESS OR 
-- IMPLIED.  MENTOR GRAPHICS SPECIFICALLY DISCLAIMS ALL IMPLIED WARRANTIES OF 
-- MERCHANTABILITY OR FITNESS FOR A PARTICULAR PURPOSE.  MENTOR GRAPHICS SHALL
-- HAVE NO RESPONSIBILITY FOR ANY DAMAGES WHATSOEVER.
-------------------------------------------------------------------------------
-- File       : q_LeadLag.vhd
-- Author     : Mentor Graphics
-- Created    : 2001/11/09
-- Last update: 2003-05-20
-------------------------------------------------------------------------------
-- Description: Lead-Lag filter with real quantity connections.
-- Includes s and z-domain architectures.
-------------------------------------------------------------------------------
-- Revisions  :
-- Date        Version     Author              Description
-- 2001/11/09  1.0         Mentor Graphics     Created
-- 2003/04/15  1.1         Mentor Graphics     Added z-domain architecture
-------------------------------------------------------------------------------
library ieee;
use ieee.math_real.all;

entity q_LeadLag is
  generic (
    K    :     real := 1.0;    -- gain
    Fp   :     real := 20.0e3; -- pole frequency (in Hz)
    Fz   :     real := 1.0e6;  -- zero frequency (in Hz)
    Fsmp :     real := 10.0e3  -- For Z-dmn only: Sample frequency (in Hz)
    );
  port (
    quantity input  : in  real;
    quantity output : out real);
end entity q_LeadLag;

-------------------------------------------------------------------------------
-- Transfer Function:
--
--              wz + s
-- H(s) = K * ---------
--              wp + s
-- 
-------------------------------------------------------------------------------

-- S Domain Implementation
architecture s_dmn of q_LeadLag is
  constant wp  : real := math_2_pi*Fp;  -- Pole freq (in radians)
  constant wz  : real := math_2_pi*Fz;  -- Zero freq (in radians)
  constant num : real_vector := (wz, 1.0);
  constant den : real_vector := (wp, 1.0);
begin
  output == K * input'ltf(num, den);    -- Laplace transform of input
end architecture s_dmn;

-- Z Domain Implementation (via bilinear transform, no pre-warping)
architecture z_dmn of q_LeadLag is
  constant T   : real := 1.0/Fsmp;      -- Sample period
  constant wz  : real := fz*math_2_pi;  -- Pole in rad/s
  constant wp  : real := fp*math_2_pi;  -- Pole in rad/s
  constant n0  : real := 2.0 + T*wz;    -- z0 numerator coefficient
  constant n1  : real := T*wz - 2.0;    -- z-1 numerator coefficient
  constant d0  : real := 2.0 + T*wp;    -- z0 denominator coefficient
  constant d1  : real := T*wp - 2.0;    -- z-1 denominator coefficient
  constant num : real_vector := (n0, n1);
  constant den : real_vector := (d0, d1);
begin  -- ztf  
  output == K*input'Ztf(num, den, T);
end z_dmn;

-------------------------------------------------------------------------------
-- Copyright (c) 2003 Mentor Graphics Corporation
-------------------------------------------------------------------------------