-------------------------------------------------------------------------------
-- Copyright (c) 2003 Mentor Graphics Corporation
--
-- This model is a component of the Mentor Graphics VHDL-AMS educational open 
-- source model library, and is covered by this license agreement. This model,
-- including any updates, modifications, revisions, copies, and documentation 
-- are copyrighted works of Mentor Graphics. USE OF THIS MODEL INDICATES YOUR 
-- COMPLETE AND UNCONDITIONAL ACCEPTANCE OF THE TERMS AND CONDITIONS SET FORTH
-- IN THIS LICENSE AGREEMENT.  Mentor Graphics grants you a non-exclusive 
-- license to use, reproduce, modify and distribute this model, provided that:
-- (a) no fee or other consideration is charged for any distribution except 
-- compilations distributed in accordance with Section (d) of this license 
-- agreement; (b) the comment text embedded in this model is included verbatim
-- in each copy of this model made or distributed by you, whether or not such 
-- version is modified; (c) any modified version must include a conspicuous 
-- notice that this model has been modified and the date of modification; and 
-- (d) any compilations sold by you that include this model must include a 
-- conspicuous notice that this model is available from Mentor Graphics in its
-- original form at no charge.
--
-- THIS MODEL IS LICENSED TO YOU "AS IS" AND WITH NO WARRANTIES, EXPRESS OR 
-- IMPLIED.  MENTOR GRAPHICS SPECIFICALLY DISCLAIMS ALL IMPLIED WARRANTIES OF 
-- MERCHANTABILITY OR FITNESS FOR A PARTICULAR PURPOSE.  MENTOR GRAPHICS SHALL
-- HAVE NO RESPONSIBILITY FOR ANY DAMAGES WHATSOEVER.
-------------------------------------------------------------------------------
-- File       : Lamp.vhd
-- Author     : Mentor Graphics
-- Created    : 2001/06/16
-- Last update: 2003/01/22
-------------------------------------------------------------------------------
-- Description: Incandescent Lamp Model
--              Default parameter setting typical for a 65 Watt/12 V
--              Automotive Headlamp
-------------------------------------------------------------------------------
-- Revisions  :
-- Date        Version     Author              Description
-- 2001/06/16  1.0         Mentor Graphics     Created 
-- 2003/01/22  1.1	   Mentor Graphics     Added temp_amb_K and temp_cold_K
-- 2003/03/28  1.2         Mentor Graphics     Modified real/temperature subtypes       
-------------------------------------------------------------------------------

-- Use proposed IEEE natures and packages
library IEEE;
use IEEE.THERMAL_SYSTEMS.all;
use IEEE.ELECTRICAL_SYSTEMS.all;

entity Lamp is

  generic (
    r_cold    : resistance  := 0.2;     -- Filament resistance at temp_cold
    temp_cold : real 	    := 27.0;    -- Calibration temperature [deg C]
    alpha     : real        := 0.0045;  -- Resistive temp coefficient [Ohms/C]
    ke        : real        := 0.85e-12;  -- Radiation coefficient
                                          -- [Watts/K^4]
    rth       : real        := 400.0;   -- Thermal resistance [C/Watt]
    cth       : real        := 0.25e-3; -- Thermal heat capacitance [Joules/C]
    temp_amb  : real 	    := 27.0);   -- Ambient temperature [deg C]

  port (terminal p1, p2 : electrical);

end entity Lamp;


library ieee;
use ieee.math_real.all;
-------------------------------------------------------------------------------
-- Dynamic Thermal Architecture
-- Equation based (behavioral) description of dynamics
-------------------------------------------------------------------------------
architecture dyn_therm of Lamp is

  constant temp_amb_K : temperature := temp_amb + 273.18;
  constant temp_cold_K : temperature := temp_cold + 273.18;

  quantity v across i through p1 to p2;
  quantity r_temp   : resistance;       -- Resistance at temp_fil [Ohms]
  quantity temp_fil : temperature;      -- Filament temperature [K]
  quantity hflow    : heat_flow;        -- Heat flow from filament [Watts]

begin

  r_temp == r_cold*(1.0 + alpha*(temp_fil - temp_cold_K));
  v      == i*r_temp;
  hflow  == v*i;
  hflow  == cth*temp_fil'dot + ke*SIGN(temp_fil - temp_amb_K)*(temp_fil**4
            - temp_amb_K**4) + (temp_fil - temp_amb_K)/rth;

  	-- Note: For alpha, cth and rth, temperatures specified in C or K will
	-- work since each represents a ratio, for which only the change in
	-- temperature is significant, not its absolute offset.

end architecture dyn_therm;

-------------------------------------------------------------------------------
-- Copyright (c) 2003 Mentor Graphics Corporation
-------------------------------------------------------------------------------